1. Module Declaration
  2. Import Declaration
  3. Symbol Name Lookup
  4. Public Imports
  5. Static Imports
  6. Renamed Imports
  7. Selective Imports
  8. Renamed and Selective Imports
  9. Scoped Imports
  10. Module Scope Operator
  11. Static Construction and Destruction
  12. Order of Static Construction
  13. Order of Static Construction within a Module
  14. Order of Static Destruction
  15. Order of Unit tests
  16. Mixin Declaration
  17. Package Module
    ModuleDeclaration DeclDefs

    DeclDef DeclDefs


Modules have a one-to-one correspondence with source files. The module name is, by default, the file name with the path and extension stripped off, and can be set explicitly with the module declaration.

Modules automatically provide a namespace scope for their contents. Modules superficially resemble classes, but differ in that:

  • There's only one instance of each module, and it is statically allocated.
  • There is no virtual table.
  • Modules do not inherit, they have no super modules, etc.
  • Only one module per file.
  • Module symbols can be imported.
  • Modules are always compiled at global scope, and are unaffected by surrounding attributes or other modifiers.

Modules can be grouped together in hierarchies called packages.

Modules offer several guarantees:

  • The order in which modules are imported does not affect the semantics.
  • The semantics of a module are not affected by what imports it.
  • If a module C imports modules A and B, any modifications to B will not silently change code in C that is dependent on A.

Module Declaration

The ModuleDeclaration sets the name of the module and what package it belongs to. If absent, the module name is taken to be the same name (stripped of path and extension) of the source file name.

    ModuleAttributesopt module ModuleFullyQualifiedName ;

    ModuleAttribute ModuleAttributes


    Packages . ModuleName


    Packages . PackageName


The Identifiers preceding the rightmost are the Packages that the module is in. The packages correspond to directory names in the source file path. Package and module names cannot be Keywords.

If present, the ModuleDeclaration appears syntactically first in the source file, and there can be only one per source file.


module c.stdio; // module stdio in the c package

By convention, package and module names are all lower case. This is because those names can have a one-to-one correspondence with the operating system's directory and file names, and many file systems are not case sensitive. All lower case package and module names will minimize problems moving projects between dissimilar file systems.

If the file name of a module is an invalid module name (e.g. foo-bar.d), you may use a module declaration to set a valid module name:

module foo_bar;

ModuleDeclaration can have an optional DeprecatedAttribute. The compiler will produce a message when the deprecated module is imported.

deprecated module foo;
module bar;
import foo;  // Deprecated: module foo is deprecated

DeprecatedAttribute can have an optional AssignExpression argument to provide a more expressive message. The AssignExpression must evaluate at compile time to a string.

deprecated("Please use foo2 instead.")
module foo;
module bar;
import foo;  // Deprecated: module foo is deprecated - Please use foo2 instead.
Implementation Defined:
  1. The mapping of package and module identifiers to directory and file names.
  2. How the deprecation messages are presented to the user.
Best Practices:
  1. PackageNames and ModuleNames should be composed of the ASCII characters lower case letters, digits or _ to ensure maximum portability and compatibility with various file systems.
  2. The file names for packages and modules should also be composed of the ASCII characters lower case letters, digits or _ and should not be a Keyword.

Import Declaration

Symbols from one module are made available in another module by using the ImportDeclaration:

    import ImportList ;
    static import ImportList ;

    Import , ImportList

    ModuleAliasIdentifier = ModuleFullyQualifiedName

    Import : ImportBindList

    ImportBind , ImportBindList

    Identifier = Identifier


There are several forms of the ImportDeclaration, from generalized to fine-grained importing.

The order in which ImportDeclarations occur has no significance.

ModuleFullyQualifiedNames in the ImportDeclaration must be fully qualified with whatever packages they are in. They are not considered to be relative to the module that imports them.

Symbol Name Lookup

The simplest form of importing is to just list the modules being imported:

module myapp.main;

import std.stdio; // import module stdio from package std

class Foo : BaseClass
    import myapp.foo;  // import module myapp.foo in this class' scope
    void bar ()
        import myapp.bar;  // import module myapp.bar in this function' scope
        writeln("hello!");  // calls std.stdio.writeln

When a symbol name is used unqualified, a two-phase lookup will happen. First, the module scope will be searched, starting from the innermost scope. For example, in the previous example, while looking for writeln, the order will be:

  • Declarations inside bar.
  • Declarations inside Foo.
  • Declarations inside BaseClass.
  • Declarations at module scope.

If the first lookup wasn't successful, a second one is performed on imports. In the second lookup phase inherited scopes are ignored. This includes scope of base classes and interface (in this example, BaseClass's imports would be ignored), as well as imports in mixed-in template.

Symbol lookup stops as soon as a symbol is found. If two symbols with the same name are found at the same lookup phase, this ambiguity will result in a compilation error.

module A;
void foo();
void bar();
module B;
void foo();
void bar();
module C;
import A;
void foo();
void test()
    foo(); // C.foo() is called, it is found before imports are searched
    bar(); // A.bar() is called, since imports are searched
module D;
import A;
import B;
void test()
    foo();   // error, A.foo() or B.foo() ?
    A.foo(); // ok, call A.foo()
    B.foo(); // ok, call B.foo()
module E;
import A;
import B;
alias foo = B.foo;
void test()
    foo();   // call B.foo()
    A.foo(); // call A.foo()
    B.foo(); // call B.foo()

Public Imports

By default, imports are private. This means that if module A imports module B, and module B imports module C, then names from C are visible only from B and not from A.

An import can be explicitly declared public, which will cause names from the imported module to be visible to further imports. So in the above example where module A imports module B, if module B publicly imports module C, names from C will be visible in A as well.

All symbols from a publicly imported module are also aliased in the importing module. Thus in the above example if C contains the name foo, it will be accessible in A as foo, B.foo and C.foo.

For another example:

module W;
void foo() { }
module X;
void bar() { }
module Y;
import W;
public import X;
foo();  // calls W.foo()
bar();  // calls X.bar()
module Z;
import Y;
foo();   // error, foo() is undefined
bar();   // ok, calls X.bar()
X.bar(); // ditto
Y.bar(); // ok, Y.bar() is an alias to X.bar()

Static Imports

static import requires use of a fully qualified name to reference the module's names:

static import std.stdio;

void main()
    writeln("hello!");           // error, writeln is undefined
    std.stdio.writeln("hello!"); // ok, writeln is fully qualified

Renamed Imports

A local name for an import can be given, through which all references to the module's symbols must be qualified with:

import io = std.stdio;

void main()
    io.writeln("hello!");        // ok, calls std.stdio.writeln
    std.stdio.writeln("hello!"); // error, std is undefined
    writeln("hello!");           // error, writeln is undefined
Best Practices: Renamed imports are handy when dealing with very long import names.

Selective Imports

Specific symbols can be exclusively imported from a module and bound into the current namespace:

import std.stdio : writeln, foo = write;

void main()
    std.stdio.writeln("hello!"); // error, std is undefined
    writeln("hello!");           // ok, writeln bound into current namespace
    write("world");              // error, write is undefined
    foo("world");                // ok, calls std.stdio.write()
    fwritefln(stdout, "abc");    // error, fwritefln undefined

static cannot be used with selective imports.

Renamed and Selective Imports

When renaming and selective importing are combined:

import io = std.stdio : foo = writeln;

void main()
    writeln("bar");           // error, writeln is undefined
    std.stdio.foo("bar");     // error, foo is bound into current namespace
    std.stdio.writeln("bar"); // error, std is undefined
    foo("bar");               // ok, foo is bound into current namespace,
                              // FQN not required
    io.writeln("bar");        // ok, io=std.stdio bound the name io in
                              // the current namespace to refer to the entire
                              //   module
    io.foo("bar");            // error, foo is bound into current namespace,
                              // foo is not a member of io

Scoped Imports

Import declarations may be used at any scope. For example:

void main()
    import std.stdio;

The imports are looked up to satisfy any unresolved symbols at that scope. Imported symbols may hide symbols from outer scopes.

In function scopes, imported symbols only become visible after the import declaration lexically appears in the function body. In other words, imported symbols at function scope cannot be forward referenced.

void main()
    void writeln(string) {}
    void foo()
        writeln("bar"); // calls main.writeln
        import std.stdio;
        writeln("bar"); // calls std.stdio.writeln
        void writeln(string) {}
        writeln("bar"); // calls main.foo.writeln
    writeln("bar"); // calls main.writeln
    std.stdio.writeln("bar");  // error, std is undefined

Module Scope Operator

A leading . causes the identifer to be looked up in the module scope.

int x;

int foo(int x)
    if (y)
        return x;  // returns foo.x, not global x
        return .x; // returns global x

Static Construction and Destruction

Static constructors are executed to initialize a module's state. Static destructors terminate a module's state.

There can be multiple static constructors and static destructors within one module. The static constructors are run in lexical order, the static destructors are run in reverse lexical order.

Non-shared static constructors and destructors are run whenever threads are created or destroyed, including the main thread.

Shared static constructors are run once on before main() is called. Shared static destructors are run after the main() returns.

import resource;

Resource x;
shared Resource y;
__gshared Resource z;

static this()  // non-shared static constructor
    x = acquireResource();

shared static this()  // shared static constructor
    y = acquireSharedResource();
    z = acquireSharedResource();

static ~this()  // non-shared static destructor

shared static ~this()   // shared static destructor
Best Practices:
  1. Shared static constructors and destructors are used to initialize and terminate shared global data.
  2. Non-shared static constructors and destructors are used to initialize and terminate thread local data.

Order of Static Construction

Shared static constructors on all modules are run before any non-shared static constructors.

The order of static initialization is implicitly determined by the import declarations in each module. Each module is assumed to depend on any imported modules being statically constructed first. There is no other imposed order on executing the module static constructors.

Cycles (circular dependencies) in the import declarations are allowed as long as not both of the modules contain static constructors or static destructors. Violation of this rule will result in a runtime exception.

Implementation Defined:
  1. An implementation may provide a means of overriding the cycle detection abort. A typical method uses the D Runtime switch --DRT-oncycle=... where the following behaviors are supported:
    1. abort The default behavior. The normal behavior as described in the previous section
    2. deprecate This functions just like abort, but upon cycle detection the runtime will use a flawed pre-2.072 algorithm to determine if the cycle was previously detected. If no cycles are detected in the old algorithm, execution continues, but a deprecation message is printed.
    3. print Print all cycles detected, but do not abort execution. When cycles are present, order of static construction is implementation defined, and not guaranteed to be valid.
    4. ignore Do not abort execution or print any cycles. When cycles are present, order of static construction is implementation defined, and not guaranteed to be valid.
Best Practices:
  1. Avoid cyclical imports where practical. They can be a sign of poor decomposition of program structure into independent modules. Two modules that import each other can often be reorganized into three modules without cycles, where the third contains declarations needed by the other two.

Order of Static Construction within a Module

Within a module, the static construction occurs in the lexical order in which they appear.

Order of Static Destruction

It is defined to be exactly the reverse order that static construction was performed in. Static destructors for individual modules will only be run if the corresponding static constructor successfully completed.

Shared static destructors are executed after static destructors.

Order of Unit tests

Unit tests are run in the lexical order in which they appear within a module.

Mixin Declaration

    mixin ( ArgumentList ) ;

Each AssignExpression in the ArgumentList is evaluated at compile time, and the result must be representable as a string. The resulting strings are concatenated to form a string. The text contents of the string must be compilable as a valid DeclDefs, and is compiled as such.

Package Module

A package module can be used to publicly import other modules, while enabling a simpler import syntax. It enables converting a module into a package of modules, without breaking existing code which uses that module. Example of a set of library modules:

module libweb.client;

void runClient() { }
module libweb.server;

void runServer() { }
module libweb;

public import libweb.client;
public import libweb.server;

The package module must have the file name package.d. The module name is declared to be the fully qualified name of the package. Package modules can be imported just like any other modules:

module test;

// import the package module
import libweb;

void main()

A package module can be nested inside of a sub-package:

// must be declared as the fully qualified name of the package, not just 'utils'
module libweb.utils;

// publicly import modules from within the 'libweb.utils' package.
public import libweb.utils.conv;
public import libweb.utils.text;

The package module can then be imported with the standard module import declaration:

module test;

// import the package module
import libweb.utils;

void main() { }

© 1999–2019 The D Language Foundation
Licensed under the Boost License 1.0.