Copyright	(c) The University of Glasgow 2001
License	BSD-style (see the file libraries/base/LICENSE)
Maintainer	[email protected]
Stability	provisional
Portability	portable
Safe Haskell	Trustworthy
Language	Haskell2010

Immutable non-strict arrays

Haskell provides indexable arrays, which may be thought of as functions whose domains are isomorphic to contiguous subsets of the integers. Functions restricted in this way can be implemented efficiently; in particular, a programmer may reasonably expect rapid access to the components. To ensure the possibility of such an implementation, arrays are treated as data, not as general functions.

Since most array functions involve the class Ix, this module is exported from Data.Array so that modules need not import both Data.Array and Data.Ix.

module Data.Ix

data Array i e Source

The type of immutable non-strict (boxed) arrays with indices in i and elements in e.

Array construction

array Source

Construct an array with the specified bounds and containing values for given indices within these bounds.

The array is undefined (i.e. bottom) if any index in the list is out of bounds. The Haskell 2010 Report further specifies that if any two associations in the list have the same index, the value at that index is undefined (i.e. bottom). However in GHC's implementation, the value at such an index is the value part of the last association with that index in the list.

Because the indices must be checked for these errors, array is strict in the bounds argument and in the indices of the association list, but non-strict in the values. Thus, recurrences such as the following are possible:

a = array (1,100) ((1,1) : [(i, i * a!(i-1)) | i <- [2..100]])

Not every index within the bounds of the array need appear in the association list, but the values associated with indices that do not appear will be undefined (i.e. bottom).

If, in any dimension, the lower bound is greater than the upper bound, then the array is legal, but empty. Indexing an empty array always gives an array-bounds error, but bounds still yields the bounds with which the array was constructed.

listArray :: Ix i => (i, i) -> [e] -> Array i e Source

Construct an array from a pair of bounds and a list of values in index order.

accumArray Source

The accumArray function deals with repeated indices in the association list using an accumulating function which combines the values of associations with the same index.

For example, given a list of values of some index type, hist produces a histogram of the number of occurrences of each index within a specified range:

hist :: (Ix a, Num b) => (a,a) -> [a] -> Array a b
hist bnds is = accumArray (+) 0 bnds [(i, 1) | i<-is, inRange bnds i]

accumArray is strict in each result of applying the accumulating function, although it is lazy in the initial value. Thus, unlike arrays built with array, accumulated arrays should not in general be recursive.

Accessing arrays

(!) :: Ix i => Array i e -> i -> e infixl 9 Source

The value at the given index in an array.

bounds :: Array i e -> (i, i) Source

The bounds with which an array was constructed.

indices :: Ix i => Array i e -> [i] Source

The list of indices of an array in ascending order.

elems :: Array i e -> [e] Source

The list of elements of an array in index order.

assocs :: Ix i => Array i e -> [(i, e)] Source

The list of associations of an array in index order.

Incremental array updates

(//) :: Ix i => Array i e -> [(i, e)] -> Array i e infixl 9 Source

Constructs an array identical to the first argument except that it has been updated by the associations in the right argument. For example, if m is a 1-origin, n by n matrix, then

m//[((i,i), 0) | i <- [1..n]]

is the same matrix, except with the diagonal zeroed.

Repeated indices in the association list are handled as for array: Haskell 2010 specifies that the resulting array is undefined (i.e. bottom), but GHC's implementation uses the last association for each index.

accum :: Ix i => (e -> a -> e) -> Array i e -> [(i, a)] -> Array i e Source

accum f takes an array and an association list and accumulates pairs from the list into the array with the accumulating function f. Thus accumArray can be defined using accum:

accumArray f z b = accum f (array b [(i, z) | i <- range b])

accum is strict in all the results of applying the accumulation. However, it is lazy in the initial values of the array.

Derived arrays

ixmap :: (Ix i, Ix j) => (i, i) -> (i -> j) -> Array j e -> Array i e Source

ixmap allows for transformations on array indices. It may be thought of as providing function composition on the right with the mapping that the original array embodies.

A similar transformation of array values may be achieved using fmap from the Array instance of the Functor class.