Methods

fold1 :: Semigroup m => t m -> m Source

Given a structure with elements whose type is a Semigroup, combine them via the semigroup's (<>) operator. This fold is right-associative and lazy in the accumulator. When you need a strict left-associative fold, use foldMap1' instead, with id as the map.

Since: base-4.18.0.0

foldMap1 :: Semigroup m => (a -> m) -> t a -> m Source

Map each element of the structure to a semigroup, and combine the results with (<>). This fold is right-associative and lazy in the accumulator. For strict left-associative folds consider foldMap1' instead.

>>> foldMap1 (:[]) (1 :| [2, 3, 4])
[1,2,3,4]

Since: base-4.18.0.0

foldMap1' :: Semigroup m => (a -> m) -> t a -> m Source

A left-associative variant of foldMap1 that is strict in the accumulator. Use this for strict reduction when partial results are merged via (<>).

>>> foldMap1' Sum (1 :| [2, 3, 4])
Sum {getSum = 10}

Since: base-4.18.0.0

toNonEmpty :: t a -> NonEmpty a Source

NonEmpty list of elements of a structure, from left to right.

>>> toNonEmpty (Identity 2)
2 :| []

Since: base-4.18.0.0

maximum :: Ord a => t a -> a Source

The largest element of a non-empty structure. This function is equivalent to foldr1 max, and its behavior on structures with multiple largest elements depends on the relevant implementation of max. For the default implementation of max (max x y = if x <= y then y else x), structure order is used as a tie-breaker: if there are multiple largest elements, the rightmost of them is chosen (this is equivalent to maximumBy compare).

>>> maximum (32 :| [64, 8, 128, 16])
128

Since: base-4.18.0.0

minimum :: Ord a => t a -> a Source

The least element of a non-empty structure. This function is equivalent to foldr1 min, and its behavior on structures with multiple largest elements depends on the relevant implementation of min. For the default implementation of min (min x y = if x <= y then x else y), structure order is used as a tie-breaker: if there are multiple least elements, the leftmost of them is chosen (this is equivalent to minimumBy compare).

>>> minimum (32 :| [64, 8, 128, 16])
8

Since: base-4.18.0.0

head :: t a -> a Source

The first element of a non-empty structure.

>>> head (1 :| [2, 3, 4])
1

Since: base-4.18.0.0

last :: t a -> a Source

The last element of a non-empty structure.

>>> last (1 :| [2, 3, 4])
4

Since: base-4.18.0.0

foldrMap1 :: (a -> b) -> (a -> b -> b) -> t a -> b Source

Right-associative fold of a structure, lazy in the accumulator.

In case of NonEmpty lists, foldrMap1, when given a function f, a binary operator g, and a list, reduces the list using g from right to left applying f to the rightmost element:

foldrMap1 f g (x1 :| [x2, ..., xn1, xn]) == x1 `g` (x2 `g` ... (xn1 `g` (f xn))...)

Note that since the head of the resulting expression is produced by an application of g to the first element of the list, if g is lazy in its right argument, foldrMap1 can produce a terminating expression from an unbounded list.

For a general Foldable1 structure this should be semantically identical to:

foldrMap1 f g = foldrMap1 f g . toNonEmpty

Since: base-4.18.0.0

foldlMap1' :: (a -> b) -> (b -> a -> b) -> t a -> b Source

Left-associative fold of a structure but with strict application of the operator.

This ensures that each step of the fold is forced to Weak Head Normal Form before being applied, avoiding the collection of thunks that would otherwise occur. This is often what you want to strictly reduce a finite structure to a single strict result.

For a general Foldable1 structure this should be semantically identical to:

foldlMap1' f z = foldlMap1' f z . toNonEmpty

Since: base-4.18.0.0

foldlMap1 :: (a -> b) -> (b -> a -> b) -> t a -> b Source

Left-associative fold of a structure, lazy in the accumulator. This is rarely what you want, but can work well for structures with efficient right-to-left sequencing and an operator that is lazy in its left argument.

In case of NonEmpty lists, foldlMap1, when given a function f, a binary operator g, and a list, reduces the list using g from left to right applying f to the leftmost element:

foldlMap1 f g (x1 :| [x2, ..., xn]) == (...(((f x1) `g` x2) `g`...) `g` xn

Note that to produce the outermost application of the operator the entire input list must be traversed. This means that foldlMap1 will diverge if given an infinite list.

If you want an efficient strict left-fold, you probably want to use foldlMap1' instead of foldlMap1. The reason for this is that the latter does not force the inner results (e.g. (f x1) `g` x2 in the above example) before applying them to the operator (e.g. to (`g` x3)). This results in a thunk chain \(O(n)\) elements long, which then must be evaluated from the outside-in.

For a general Foldable1 structure this should be semantically identical to:

foldlMap1 f g = foldlMap1 f g . toNonEmpty

Since: base-4.18.0.0

foldrMap1' :: (a -> b) -> (a -> b -> b) -> t a -> b Source

foldrMap1' is a variant of foldrMap1 that performs strict reduction from right to left, i.e. starting with the right-most element. The input structure must be finite, otherwise foldrMap1' runs out of space (diverges).

If you want a strict right fold in constant space, you need a structure that supports faster than \(O(n)\) access to the right-most element.

This method does not run in constant space for structures such as NonEmpty lists that don't support efficient right-to-left iteration and so require \(O(n)\) space to perform right-to-left reduction. Use of this method with such a structure is a hint that the chosen structure may be a poor fit for the task at hand. If the order in which the elements are combined is not important, use foldlMap1' instead.

Since: base-4.18.0.0

>>> intercalate1 ", " $ "hello" :| ["how", "are", "you"]
"hello, how, are, you"

>>> intercalate1 ", " $ "hello" :| []
"hello"

>>> intercalate1 mempty $ "I" :| ["Am", "Fine", "You?"]
"IAmFineYou?"