W3cubDocs

/Phoenix

Plug v1.7.1 Plug.Router

A DSL to define a routing algorithm that works with Plug.

It provides a set of macros to generate routes. For example:

defmodule AppRouter do
  use Plug.Router

  plug :match
  plug :dispatch

  get "/hello" do
    send_resp(conn, 200, "world")
  end

  match _ do
    send_resp(conn, 404, "oops")
  end
end

Each route needs to return a connection, as per the Plug spec. A catch-all match is recommended to be defined as in the example above, otherwise routing fails with a function clause error.

The router is itself a plug, which means it can be invoked as:

AppRouter.call(conn, AppRouter.init([]))

Notice the router contains a plug pipeline and by default it requires two plugs: match and dispatch. match is responsible for finding a matching route which is then forwarded to dispatch. This means users can easily hook into the router mechanism and add behaviour before match, before dispatch or after both.

To specify private options on match that can be used by plugs before dispatch pass an option with key :private containing a map. Example:

get "/hello", private: %{an_option: :a_value} do
  send_resp(conn, 200, "world")
end

These options are assigned to :private in the call’s Plug.Conn.

Routes

get "/hello" do
  send_resp(conn, 200, "world")
end

In the example above, a request will only match if it is a GET request and the route is “/hello”. The supported HTTP methods are get, post, put, patch, delete and options.

A route can also specify parameters which will then be available in the function body:

get "/hello/:name" do
  send_resp(conn, 200, "hello #{name}")
end

The :name parameter will also be available in the function body as conn.params["name"] and conn.path_params["name"].

Routes allow for globbing which will match the remaining parts of a route and can be available as a parameter in the function body. Also note that a glob can’t be followed by other segments:

get "/hello/*_rest" do
  send_resp(conn, 200, "matches all routes starting with /hello")
end

get "/hello/*glob" do
  send_resp(conn, 200, "route after /hello: #{inspect glob}")
end

Finally, a general match function is also supported:

match "/hello" do
  send_resp(conn, 200, "world")
end

A match will match any route regardless of the HTTP method. Check match/3 for more information on how route compilation works and a list of supported options.

Parameter Parsing

Handling request data can be done through the Plug.Parsers plug. It provides support for parsing URL-encoded, form-data, and JSON data as well as providing a behaviour that others parsers can adopt.

Here is an example of Plug.Parsers can be used in a Plug.Router router to parse the JSON-encoded body of a POST request:

defmodule AppRouter do
  use Plug.Router

  plug :match
  plug Plug.Parsers, parsers: [:json],
                     pass:  ["application/json"],
                     json_decoder: Jason
  plug :dispatch

  post "/hello" do
    IO.inspect conn.body_params # Prints JSON POST body
    send_resp(conn, 200, "Success!")
  end
end

It is important that Plug.Parsers is placed before the :dispatch plug in the pipeline, otherwise the matched clause route will not receive the parsed body in its Plug.Conn argument when dispatched.

Plug.Parsers can also be plugged between :match and :dispatch (like in the example above): this means that Plug.Parsers will run only if there is a matching route. This can be useful to perform actions such as authentication before parsing the body, which should only be parsed if a route matches afterwards.

Error handling

In case something goes wrong in a request, the router by default will crash, without returning any response to the client. This behaviour can be configured in two ways, by using two different modules:

  • Plug.ErrorHandler - allows the developer to customize exactly which page is sent to the client via the handle_errors/2 function;

  • Plug.Debugger - automatically shows debugging and request information about the failure. This module is recommended to be used only in a development environment.

Here is an example of how both modules could be used in an application:

defmodule AppRouter do
  use Plug.Router

  if Mix.env == :dev do
    use Plug.Debugger
  end

  use Plug.ErrorHandler

  plug :match
  plug :dispatch

  get "/hello" do
    send_resp(conn, 200, "world")
  end

  defp handle_errors(conn, %{kind: _kind, reason: _reason, stack: _stack}) do
    send_resp(conn, conn.status, "Something went wrong")
  end
end

Routes compilation

All routes are compiled to a match function that receives three arguments: the method, the request path split on / and the connection. Consider this example:

match "/foo/bar", via: :get do
  send_resp(conn, 200, "hello world")
end

It is compiled to:

defp match("GET", ["foo", "bar"], conn) do
  send_resp(conn, 200, "hello world")
end

This means guards can be given to match:

match "/foo/bar/:baz" when size(baz) <= 3, via: :get do
  send_resp(conn, 200, "hello world")
end

After a match is found, the block given as do/end is stored as a function in the connection. This function is then retrieved and invoked in the dispatch plug.

Options

When used, the following options are accepted by Plug.Router:

  • :log_on_halt - accepts the level to log whenever the request is halted

Summary

Functions

delete(path, options, contents \\ [])

Dispatches to the path only if the request is a DELETE request. See match/3 for more examples

forward(path, options)

Forwards requests to another Plug. The path_info of the forwarded connection will exclude the portion of the path specified in the call to forward. If the path contains any parameters, those will be available in the target Plug in conn.params and conn.path_params

get(path, options, contents \\ [])

Dispatches to the path only if the request is a GET request. See match/3 for more examples

match(path, options, contents \\ [])

Main API to define routes

match_path(conn)

Returns the path of the route that the request was matched to

options(path, options, contents \\ [])

Dispatches to the path only if the request is an OPTIONS request. See match/3 for more examples

patch(path, options, contents \\ [])

Dispatches to the path only if the request is a PATCH request. See match/3 for more examples

post(path, options, contents \\ [])

Dispatches to the path only if the request is a POST request. See match/3 for more examples

put(path, options, contents \\ [])

Dispatches to the path only if the request is a PUT request. See match/3 for more examples

Functions

Link to this macro delete(path, options, contents \\ []) (macro)

Dispatches to the path only if the request is a DELETE request. See match/3 for more examples.

Link to this macro forward(path, options) (macro)

Forwards requests to another Plug. The path_info of the forwarded connection will exclude the portion of the path specified in the call to forward. If the path contains any parameters, those will be available in the target Plug in conn.params and conn.path_params.

Options

forward accepts the following options:

  • :to - a Plug the requests will be forwarded to.
  • :init_opts - the options for the target Plug.
  • :host - a string representing the host or subdomain, exactly like in match/3.
  • :private - values for conn.private, exactly like in match/3.
  • :assigns - values for conn.assigns, exactly like in match/3.

If :init_opts is undefined, then all remaining options are passed to the target plug.

Examples

forward "/users", to: UserRouter

Assuming the above code, a request to /users/sign_in will be forwarded to the UserRouter plug, which will receive what it will see as a request to /sign_in.

forward "/foo/:bar/qux", to: FooPlug

Here, a request to /foo/BAZ/qux will be forwarded to the FooPlug plug, which will receive what it will see as a request to /, and conn.params["bar"] will be set to "BAZ".

Some other examples:

forward "/foo/bar", to: :foo_bar_plug, host: "foobar."
forward "/baz", to: BazPlug, init_opts: [plug_specific_option: true]
Link to this macro get(path, options, contents \\ []) (macro)

Dispatches to the path only if the request is a GET request. See match/3 for more examples.

Link to this macro match(path, options, contents \\ []) (macro)

Main API to define routes.

It accepts an expression representing the path and many options allowing the match to be configured.

The route can dispatch either to a function body or a Plug module.

Examples

match "/foo/bar", via: :get do
  send_resp(conn, 200, "hello world")
end

match "/baz", to: MyPlug, init_opts: [an_option: :a_value]

Options

match/3 and the other route macros accept the following options:

  • :host - the host which the route should match. Defaults to nil, meaning no host match, but can be a string like “example.com” or a string ending with “.”, like “subdomain.” for a subdomain match.

  • :private - assigns values to conn.private for use in the match

  • :assigns - assigns values to conn.assigns for use in the match

  • :via - matches the route against some specific HTTP method (specified as an atom, like :get or :put.

  • :do - contains the implementation to be invoked in case the route matches.

  • :to - a Plug that will be called in case the route matches.

  • :init_opts - the options for the target Plug given by :to.

A route should specify only one of :do or :to options.

Link to this function match_path(conn)
match_path(Plug.Conn.t()) :: String.t()

Returns the path of the route that the request was matched to.

Link to this macro options(path, options, contents \\ []) (macro)

Dispatches to the path only if the request is an OPTIONS request. See match/3 for more examples.

Link to this macro patch(path, options, contents \\ []) (macro)

Dispatches to the path only if the request is a PATCH request. See match/3 for more examples.

Link to this macro post(path, options, contents \\ []) (macro)

Dispatches to the path only if the request is a POST request. See match/3 for more examples.

Link to this macro put(path, options, contents \\ []) (macro)

Dispatches to the path only if the request is a PUT request. See match/3 for more examples.

© 2013 Plataformatec
Licensed under the Apache License, Version 2.0.
https://hexdocs.pm/plug/1.7.1/Plug.Router.html