Process package

The Process package provides support for handling Unix style processes. For each external process that you want to handle, you need to create a ProcessMonitor and a corresponding ProcessNotify object. Each ProcessMonitor runs as it own actor and upon receiving data will call its corresponding ProcessNotify's method.

Example program

The following program will spawn an external program and write to it's STDIN. Output received on STDOUT of the child process is forwarded to the ProcessNotify client and printed.

use "process"
use "files"

actor Main
  new create(env: Env) =>
    // create a notifier
    let client = ProcessClient(env)
    let notifier: ProcessNotify iso = consume client
    // define the binary to run
    try
      let path = FilePath(env.root as AmbientAuth, "/bin/cat")?
      // define the arguments; first arg is always the binary name
      let args: Array[String] val = ["cat"]
      // define the environment variable for the execution
      let vars: Array[String] val = ["HOME=/"; "PATH=/bin"]
      // create a ProcessMonitor and spawn the child process
      let auth = env.root as AmbientAuth
      let pm: ProcessMonitor = ProcessMonitor(auth, auth, consume notifier,
      path, args, vars)
      // write to STDIN of the child process
      pm.write("one, two, three")
      pm.done_writing() // closing stdin allows cat to terminate
    else
      env.out.print("Could not create FilePath!")
    end

// define a client that implements the ProcessNotify interface
class ProcessClient is ProcessNotify
  let _env: Env

  new iso create(env: Env) =>
    _env = env

  fun ref stdout(process: ProcessMonitor ref, data: Array[U8] iso) =>
    let out = String.from_array(consume data)
    _env.out.print("STDOUT: " + out)

  fun ref stderr(process: ProcessMonitor ref, data: Array[U8] iso) =>
    let err = String.from_array(consume data)
    _env.out.print("STDERR: " + err)

  fun ref failed(process: ProcessMonitor ref, err: ProcessError) =>
    match err
    | ExecveError => _env.out.print("ProcessError: ExecveError")
    | PipeError => _env.out.print("ProcessError: PipeError")
    | ForkError => _env.out.print("ProcessError: ForkError")
    | WaitpidError => _env.out.print("ProcessError: WaitpidError")
    | WriteError => _env.out.print("ProcessError: WriteError")
    | KillError => _env.out.print("ProcessError: KillError")
    | CapError => _env.out.print("ProcessError: CapError")
    | Unsupported => _env.out.print("ProcessError: Unsupported")
    else _env.out.print("Unknown ProcessError!")
    end

  fun ref dispose(process: ProcessMonitor ref, child_exit_code: I32) =>
    let code: I32 = consume child_exit_code
    _env.out.print("Child exit code: " + code.string())

Process portability

The ProcessMonitor supports spawning processes on Linux, FreeBSD and OSX. Processes are not supported on Windows and attempting to use them will cause a runtime error.

Shutting down ProcessMonitor and external process

Document waitpid behaviour (stops world)

Public Types

• interface ProcessNotify
• primitive ExecveError
• primitive PipeError
• primitive ForkError
• primitive WaitpidError
• primitive WriteError
• primitive KillError
• primitive Unsupported
• primitive CapError
• type ProcessError
• type ProcessMonitorAuth
• actor ProcessMonitor
• primitive StartProcessAuth
• primitive CatPath
• primitive CatArgs
• primitive EchoPath

Private Types

• class _ProcessClient
• primitive _STDINFILENO
• primitive _STDOUTFILENO
• primitive _STDERRFILENO
• primitive _EPERM
• primitive _ESRCH
• primitive _EINTR
• primitive _EAGAIN
• primitive _EINVAL
• interface _Process
• class _ProcessNone
• class _ProcessPosix
• class _ProcessWindows
• primitive _FSETFL
• primitive _FGETFL
• primitive _FSETFD
• primitive _FGETFD
• primitive _FDCLOEXEC
• primitive _ONONBLOCK
• primitive _ERRORBROKENPIPE
• primitive _ERRORNODATA
• class _Pipe