class Monad m => MonadCont (m :: Type -> Type) where Source

label :: MonadCont m => a -> m (a -> m b, a) Source

Introduces a recursive binding to the continuation. Due to the use of callCC, calling the continuation will interrupt execution of the current block creating an effect similar to goto/setjmp in C.

Since: mtl-2.3.1

label_ :: MonadCont m => m (m a) Source

Simplified version of label without arguments.

Since: mtl-2.3.1

type Cont r = ContT r Identity Source

Continuation monad. Cont r a is a CPS ("continuation-passing style") computation that produces an intermediate result of type a within a CPS computation whose final result type is r.

The return function simply creates a continuation which passes the value on.

The >>= operator adds the bound function into the continuation chain.

cont :: ((a -> r) -> r) -> Cont r a Source

Construct a continuation-passing computation from a function. (The inverse of runCont)

runCont Source

The result of running a CPS computation with a given final continuation. (The inverse of cont)

evalCont :: Cont r r -> r Source

The result of running a CPS computation with the identity as the final continuation.

• evalCont (return x) = x

mapCont :: (r -> r) -> Cont r a -> Cont r a Source

Apply a function to transform the result of a continuation-passing computation.

• runCont (mapCont f m) = f . runCont m

withCont :: ((b -> r) -> a -> r) -> Cont r a -> Cont r b Source

Apply a function to transform the continuation passed to a CPS computation.

• runCont (withCont f m) = runCont m . f

newtype ContT (r :: k) (m :: k -> Type) a Source

The continuation monad transformer. Can be used to add continuation handling to any type constructor: the Monad instance and most of the operations do not require m to be a monad.

ContT is not a functor on the category of monads, and many operations cannot be lifted through it.

runContT :: ContT r m a -> (a -> m r) -> m r Source

evalContT :: Monad m => ContT r m r -> m r Source

The result of running a CPS computation with return as the final continuation.

• evalContT (lift m) = m

mapContT :: forall {k} m (r :: k) a. (m r -> m r) -> ContT r m a -> ContT r m a Source

Apply a function to transform the result of a continuation-passing computation. This has a more restricted type than the map operations for other monad transformers, because ContT does not define a functor in the category of monads.

• runContT (mapContT f m) = f . runContT m

withContT :: forall {k} b m (r :: k) a. ((b -> m r) -> a -> m r) -> ContT r m a -> ContT r m b Source

Apply a function to transform the continuation passed to a CPS computation.

• runContT (withContT f m) = runContT m . f

Calculating length of a list continuation-style:

calculateLength :: [a] -> Cont r Int
calculateLength l = return (length l)

Here we use calculateLength by making it to pass its result to print:

main = do
  runCont (calculateLength "123") print
  -- result: 3

It is possible to chain Cont blocks with >>=.

double :: Int -> Cont r Int
double n = return (n * 2)

main = do
  runCont (calculateLength "123" >>= double) print
  -- result: 6

This example gives a taste of how escape continuations work, shows a typical pattern for their usage.

-- Returns a string depending on the length of the name parameter.
-- If the provided string is empty, returns an error.
-- Otherwise, returns a welcome message.
whatsYourName :: String -> String
whatsYourName name =
  (`runCont` id) $ do                      -- 1
    response <- callCC $ \exit -> do       -- 2
      validateName name exit               -- 3
      return $ "Welcome, " ++ name ++ "!"  -- 4
    return response                        -- 5

validateName name exit = do
  when (null name) (exit "You forgot to tell me your name!")

Here is what this example does:

1. Runs an anonymous Cont block and extracts value from it with (`runCont` id). Here id is the continuation, passed to the Cont block.
1. Binds response to the result of the following callCC block, binds exit to the continuation.
1. Validates name. This approach illustrates advantage of using callCC over return. We pass the continuation to validateName, and interrupt execution of the Cont block from inside of validateName.
1. Returns the welcome message from the callCC block. This line is not executed if validateName fails.
1. Returns from the Cont block.

ContT can be used to add continuation handling to other monads. Here is an example how to combine it with IO monad:

import Control.Monad.Cont
import System.IO

main = do
  hSetBuffering stdout NoBuffering
  runContT (callCC askString) reportResult

askString :: (String -> ContT () IO String) -> ContT () IO String
askString next = do
  liftIO $ putStrLn "Please enter a string"
  s <- liftIO $ getLine
  next s

reportResult :: String -> IO ()
reportResult s = do
  putStrLn ("You entered: " ++ s)

Action askString requests user to enter a string, and passes it to the continuation. askString takes as a parameter a continuation taking a string parameter, and returning IO (). Compare its signature to runContT definition.

The early exit behavior of callCC can be leveraged to produce other idioms:

whatsYourNameLabel :: IO ()
whatsYourNameLabel = evalContT $ do
  (beginning, attempts) <- label (0 :: Int)
  liftIO $ putStrLn $ "Attempt #" <> show attempts
  liftIO $ putStrLn $ "What's your name?"
  name <- liftIO getLine
  when (null name) $ beginning (attempts + 1)
  liftIO $ putStrLn $ "Welcome, " ++ name ++ "!"

Calling beggining will interrupt execution of the block, skipping the welcome message, which will be printed only once at the very end of the loop.