class Log

• Log
• Reference
• Object

Overview

The Log class provides a logging utility that you can use to output messages.

The messages, or Log::Entry have associated levels, such as Info or Error that indicate their importance. See Log::Severity.

To log a message #trace, #debug, #info, #notice, #warn, #error, and #fatal methods can be used. They expect a block that will evaluate to the message of the entry.

require "log"

Log.info { "Program started" }

Data can be associated with a log entry via the Log::Emitter yielded in the logging methods.

Log.info &.emit("User logged in", user_id: 42)

If you want to log an exception, you can indicate it in the exception: named argument.

Log.warn(exception: e) { "Oh no!" }
Log.warn exception: e, &.emit("Oh no!", user_id: 42)

The block is only evaluated if the current message is to be emitted to some Log::Backend.

To add structured information to the message you can use the Log::Context.

When creating log messages they belong to a source. If the top-level Log is used as in the above examples its source is the empty string.

The source can be used to identify the module or part of the application that is logging. You can configure for each source a different level to filter the messages.

A recommended pattern is to declare a Log constant in the namespace of your shard or module as follows:

module DB
  Log = ::Log.for("db") # => Log for db source

  def do_something
    Log.info { "this is logged in db source" }
  end
end

DB::Log.info { "this is also logged in db source" }
Log.for("db").info { "this is also logged in db source" }
Log.info { "this is logged in top-level source" }

That way, any Log.info call within the DB module will use the db source. And not the top-level ::Log.info.

Sources can be nested. Continuing the last example, to declare a Log constant db.pool source you can do as follows:

class DB::Pool
  Log = DB::Log.for("pool") # => Log for db.pool source
end

A Log will emit the messages to the Log::Backends attached to it as long as the configured severity filter #level permits it.

Logs can also be created from a type directly. For the type DB::Pool the source db.pool will be used. For generic types as Foo::Bar(Baz) the source foo.bar will be used (i.e. without generic arguments).

module DB
  Log = ::Log.for(self) # => Log for db source
end

Default logging configuration

By default entries from all sources with Info and above severity will be logged to STDOUT using the Log::IOBackend.

If you need to change the default level, backend or sources call Log.setup upon startup.

Log.setup(:debug)                     # Log debug and above for all sources to STDOUT
Log.setup("myapp.*, http.*", :notice) # Log notice and above for myapp.* and http.* sources only, and log nothing for any other source.
backend_with_formatter = Log::IOBackend.new(formatter: custom_formatter)
Log.setup(:debug, backend_with_formatter) # Log debug and above for all sources to using a custom backend

Configure logging explicitly in the code

Use Log.setup methods to indicate which sources should go to which backends.

You can indicate actual sources or patterns.

• the empty string matches only the top-level source
• * matches all the sources
• foo.bar.* matches foo.bar and every nested source
• foo.bar matches foo.bar, but not its nested sources
• Any comma separated combination of the above

The following configuration will setup for all sources to emit warnings (or higher) to STDOUT, allow any of the db.* and nested source to emit debug (or higher), and to also emit for all sources errors (or higher) to an elasticsearch backend.

Log.setup |c|
  backend = Log::IOBackend.new

  c.bind "*", :warn, backend
  c.bind "db.*", :debug, backend
  c.bind "*", :error, ElasticSearchBackend.new("http://localhost:9200")
end

Configure logging from environment variables

Include the following line to allow configuration from environment variables.

Log.setup_from_env

The environment variable LOG_LEVEL is used to indicate which severity level to emit. By default entries from all sources with Info and above severity will be logged to STDOUT using the Log::IOBackend.

To change the level and sources change the environment variable value:

$ LOG_LEVEL=DEBUG ./bin/app

You can tweak the default values (used when LOG_LEVEL variable is not defined):

Log.setup_from_env(default_level: :error)

Defined in:

Constructors

• .for(type : Class, level : Severity? = nil) : Log

  Creates a Log for the given type.

• .for(source : String, level : Severity? = nil) : Log

  Creates a Log for the given source.

Class Method Summary

• .builder

  Returns the default Log::Builder used for Log.for calls.

• .capture(source : String = "*", level : Severity = Log::Severity::Trace, *, builder = Log.builder, &)

  Returns and yields an EntriesChecker that allows checking specific log entries were emitted.

• .capture(level : Log::Severity = Log::Severity::Trace, *, builder : Log::Builder = Log.builder, &)

  Returns and yields an EntriesChecker that allows checking specific log entries were emitted.

• .context : Log::Context

  Returns the current fiber logging context.

• .context=(value : Log::Metadata)

  Sets the current fiber logging context.

• .context=(value : Log::Context)

  Sets the current fiber logging context.

• .debug(*, exception : Exception? = nil, &)

  See Log#debug.

• .error(*, exception : Exception? = nil, &)

  See Log#error.

• .fatal(*, exception : Exception? = nil, &)

  See Log#fatal.

• .info(*, exception : Exception? = nil, &)

  See Log#info.

• .notice(*, exception : Exception? = nil, &)

  See Log#notice.

• .progname

  The program name used for log entries

• .progname=(progname)

  The program name used for log entries

• .setup(*, builder : Log::Builder = Log.builder, &)

  Setups logging bindings discarding all previous configurations.

• .setup(sources : String = "*", level : Log::Severity = Log::Severity::Info, backend : Log::Backend = IOBackend.new, *, builder : Log::Builder = Log.builder)

  Setups logging for sources using the specified level, backend.

• .setup(level : Log::Severity = Log::Severity::Info, backend : Log::Backend = IOBackend.new, *, builder : Log::Builder = Log.builder)

  Setups logging for all sources using the specified level, backend.

• .setup_from_env(*, builder : Log::Builder = Log.builder, level : String, sources : String, backend = Log::IOBackend.new)

  DEPRECATED Use default_level, default_sources named arguments

• .setup_from_env(*, builder : Log::Builder = Log.builder, default_level : Log::Severity = Log::Severity::Info, default_sources = "*", log_level_env = "LOG_LEVEL", backend = Log::IOBackend.new)

  Setups logging based on LOG_LEVEL environment variable.

• .trace(*, exception : Exception? = nil, &)

  See Log#trace.

• .warn(*, exception : Exception? = nil, &)

  See Log#warn.

• .with_context(&)

  Method to save and restore the current logging context.

Instance Method Summary

• #backend : Backend?
• #context : Log::Context

  Returns the current fiber logging context.

• #context=(value : Log::Metadata | Log::Context)

  Sets the current fiber logging context.

• #debug(*, exception : Exception? = nil, &)

  Logs a message if the logger's current severity is lower or equal to 1.

• #error(*, exception : Exception? = nil, &)

  Logs a message if the logger's current severity is lower or equal to 5.

• #fatal(*, exception : Exception? = nil, &)

  Logs a message if the logger's current severity is lower or equal to 6.

• #for(child_source : String, level : Severity? = nil) : Log

  Creates a Log for the given nested source.

• #for(type : Class, level : Severity? = nil) : Log

  Creates a Log for the given type.

• #info(*, exception : Exception? = nil, &)

  Logs a message if the logger's current severity is lower or equal to 2.

• #level : Severity
• #level=(value : Severity)

  Change this log severity level filter.

• #notice(*, exception : Exception? = nil, &)

  Logs a message if the logger's current severity is lower or equal to 3.

• #source : String
• #trace(*, exception : Exception? = nil, &)

  Logs a message if the logger's current severity is lower or equal to 0.

• #warn(*, exception : Exception? = nil, &)

  Logs a message if the logger's current severity is lower or equal to 4.

• #with_context(&)

  Method to save and restore the current logging context.

Macro Summary

• define_formatter(name, pattern)

  Generate subclasses of Log::StaticFormatter from a string with interpolations

Constructor Detail

Class Method Detail

require "spec"
require "log"
require "log/spec"

Log.setup(:none)

def greet(name)
  Log.info { "Greeting #{name}" }
end

it "greets" do
  Log.capture do |logs|
    greet("Harry")
    greet("Hermione")
    greet("Ron")

    logs.check(:info, /greeting harry/i)
    logs.next(:info, /greeting hermione/i)
  end
end

require "spec"
require "log"
require "log/spec"

Log.setup(:none)

def greet(name)
  Log.info { "Greeting #{name}" }
end

it "greets" do
  Log.capture do |logs|
    greet("Harry")
    greet("Hermione")
    greet("Ron")

    logs.check(:info, /greeting harry/i)
    logs.next(:info, /greeting hermione/i)
  end
end

Log.context.set a: 1
Log.info { %(message with {"a" => 1} context) }
Log.with_context do
  Log.context.set b: 2
  Log.info { %(message with {"a" => 1, "b" => 2} context) }
end
Log.info { %(message with {"a" => 1} context) }

Instance Method Detail

Log.context.set a: 1
Log.info { %(message with {"a" => 1} context) }
Log.with_context do
  Log.context.set b: 2
  Log.info { %(message with {"a" => 1, "b" => 2} context) }
end
Log.info { %(message with {"a" => 1} context) }

Macro Detail

Log.define_formatter MyFormat, "- #{severity}: #{message}"